(use-modules
 (ice-9 filesystem)
 (ordo)
 (ordo connection)
 (ordo logger))

(define* (install-aws-cli conn #:key (url "https://awscli.amazonaws.com/awscli-exe-linux-x86_64.zip") update? install-dir bin-dir)
  (let ((tmp-dir (run conn "mktemp" "-d" #:return car #:check? #t)))
    (dynamic-wind
      (const #t)
      (lambda ()
        (let ((zipfile (file-name-join* tmp-dir (file-basename url))))
          (run conn "wget" "-O" zipfile url #:check? #t)
          (run conn "unzip" zipfile "-d" tmp-dir #:check? #t)
          (run conn (file-name-join* tmp-dir "aws" "install")
               (when install-dir `("-i" ,install-dir))
               (when bin-dir `("-b" ,bin-dir))
               (when update? "-u")
               #:check? #t)))
      (lambda ()
        (run conn "rm" "-rf" tmp-dir #:check? #t)))))

(define test-playbook
  (playbook "Test Playbook"
            (play "Test play"
                  #:connection (local-connection)
                  (task "Get home directory"
                        (lambda (c) (run c "sh" "-c" "[ -n \"$HOME\" ] && echo $HOME" #:check? #t #:return car))
                        #:register (register-play-var 'home-dir)
                        #:tags '(#:always))
                  (task "Install AWS CLI"
                        (lambda (c)
                          (install-aws-cli c
                                           #:update? #t
                                           #:install-dir (file-name-join* ($ 'home-dir) ".local" "aws-cli")
                                           #:bin-dir (file-name-join* ($ 'home-dir) ".local" "bin")))))))

(setup-logging)
(run-playbook test-playbook)