ordo/modules/ordo/task.scm

(define-module (ordo task)
  #:use-module (ice-9 match)
  #:use-module (srfi srfi-1) ; list utils
  #:use-module (srfi srfi-9) ; records
  #:use-module (srfi srfi-26) ; cut
  #:use-module (ordo context)
  #:export (task
            task?
            task-description
            task-action
            task-register
            task-triggers
            run-task))

(define-record-type <task>
  (make-task description action register triggers)
  task?
  (description task-description)
  (action task-action)
  (register task-register)
  (triggers task-triggers))

(define* (task description action #:key (register #f) (triggers '()))
  (make-task description action register triggers))

(define (run-task ctx t)
  (match t
    (($ <task> description action register triggers)
     (format #t "RUNNING TASK ~a~%" description)
     (let ((result (action ctx)))
       (when register
         (register-context-var! ctx register result))
       (when triggers
         (add-context-triggers! ctx triggers))))))